Add DEFAULT_RECORDING_VISIBILITY and DEFAULT_STREAM_VISIBILITY config options

Author: ku1ik

config/runtime.exs

@@ -252,4 +252,17 @@ if config_env() in [:prod, :dev] do
   if email = env.("CONTACT_EMAIL_ADDRESS") do
     config :asciinema, contact_email_address: email
   end
+
+  visibility = env.("DEFAULT_RECORDING_VISIBILITY")
+
+  if visibility in ~w[private unlisted public] do
+    config :asciinema, Asciinema.Accounts,
+      default_recording_visibility: String.to_atom(visibility)
+  end
+
+  visibility = env.("DEFAULT_STREAM_VISIBILITY")
+
+  if visibility in ~w[private unlisted public] do
+    config :asciinema, Asciinema.Accounts, default_stream_visibility: String.to_atom(visibility)
+  end
 end

lib/asciinema.ex

@@ -1,8 +1,8 @@
 defmodule Asciinema do
   alias Asciinema.{Accounts, Emails, Recordings, Repo, Streaming}
 
-  def create_user_from_email(email) do
-    with {:ok, user} <- Accounts.create_user_from_email(email) do
+  def create_user(attrs) do
+    with {:ok, user} <- Accounts.create_user(attrs) do
       if Streaming.mode() == :static do
         Streaming.create_stream!(user)
       end
@@ -11,6 +11,19 @@ defmodule Asciinema do
     end
   end
 
+  def create_user_from_sign_up_token(token) do
+    with {:ok, email} <- Accounts.verify_sign_up_token(token),
+         {:ok, user} <- create_user(%{email: email}) do
+      {:ok, user}
+    else
+      {:error, %Ecto.Changeset{errors: [{:email, _}]}} ->
+        {:error, :email_taken}
+
+      result ->
+        result
+    end
+  end
+
   defdelegate change_user(user, params \\ %{}), to: Accounts
 
   def update_user(user, params) do
@@ -21,12 +34,6 @@ defmodule Asciinema do
     end
   end
 
-  def create_user_from_sign_up_token(token) do
-    with {:ok, email} <- Accounts.verify_sign_up_token(token) do
-      create_user_from_email(email)
-    end
-  end
-
   def send_login_email(identifier, url_provider, opts \\ []) do
     case Accounts.generate_login_token(identifier, opts) do
       {:ok, {type, token, email}} ->
@@ -43,6 +50,7 @@ defmodule Asciinema do
     Emails.send_email(:account_deletion, user.email, token, url_provider)
   end
 
+  defdelegate generate_login_token(email), to: Accounts
   defdelegate verify_login_token(token), to: Accounts
 
   def register_cli(user, token) do

lib/asciinema/accounts.ex

@@ -47,35 +47,29 @@ defmodule Asciinema.Accounts do
     Repo.all(from(u in User, order_by: [asc: :id], limit: ^limit))
   end
 
+  def build_user(attrs \\ %{}) do
+    Changeset.change(
+      %User{
+        default_recording_visibility: config(:default_recording_visibility, :unlisted),
+        default_stream_visibility: config(:default_stream_visibility, :unlisted)
+      },
+      attrs
+    )
+  end
+
   def create_user(attrs) do
     import Ecto.Changeset
 
-    %User{}
+    build_user()
     |> cast(attrs, [:email, :username])
     |> validate_required([:email])
     |> update_change(:email, &String.downcase/1)
     |> validate_format(:email, @valid_email_re)
+    |> validate_username()
     |> add_contraints()
     |> Repo.insert()
   end
 
-  def create_user_from_email(email) do
-    import Ecto.Changeset
-
-    result =
-      %User{}
-      |> cast(%{email: email}, [:email])
-      |> validate_required([:email])
-      |> update_change(:email, &String.downcase/1)
-      |> validate_format(:email, @valid_email_re)
-      |> add_contraints()
-      |> Repo.insert()
-
-    with {:error, %Ecto.Changeset{errors: [{:email, _}]}} <- result do
-      {:error, :email_taken}
-    end
-  end
-
   def ensure_asciinema_user do
     case Repo.get_by(User, username: "asciinema") do
       nil ->
@@ -85,17 +79,15 @@ defmodule Asciinema.Accounts do
           email: "[email protected]"
         }
 
-        %User{}
-        |> change_user(attrs)
+        attrs
+        |> build_user()
         |> Repo.insert!()
 
       user ->
         user
     end
   end
 
-  def new_user, do: change_user(%User{})
-
   def change_user(user, params \\ %{}) do
     import Ecto.Changeset
 
@@ -108,18 +100,26 @@ defmodule Asciinema.Accounts do
       :theme_prefer_original,
       :terminal_font_family,
       :default_recording_visibility,
+      :default_stream_visibility,
       :stream_recording_enabled
     ])
     |> validate_required([:email])
     |> update_change(:email, &String.downcase/1)
     |> validate_format(:email, @valid_email_re)
-    |> validate_format(:username, @valid_username_re)
-    |> validate_length(:username, min: 2, max: 16)
+    |> validate_username()
     |> validate_inclusion(:theme_name, Themes.terminal_themes())
     |> validate_inclusion(:terminal_font_family, Fonts.terminal_font_families())
     |> add_contraints()
   end
 
+  defp validate_username(changeset) do
+    import Ecto.Changeset
+
+    changeset
+    |> validate_format(:username, @valid_username_re)
+    |> validate_length(:username, min: 2, max: 16)
+  end
+
   defp add_contraints(changeset) do
     import Ecto.Changeset
 
@@ -298,9 +298,9 @@ defmodule Asciinema.Accounts do
   end
 
   defp create_tmp_user(username) do
-    username = String.slice(username, 0, 16)
-
-    Repo.insert!(%User{temporary_username: username})
+    %{temporary_username: String.slice(username, 0, 16)}
+    |> build_user()
+    |> Repo.insert!()
   end
 
   defp check_cli_ownership(user, cli) do

lib/asciinema/accounts/user.ex

@@ -14,11 +14,8 @@ defmodule Asciinema.Accounts.User do
     field :terminal_font_family, :string
     field :streaming_enabled, :boolean, default: true
     field :stream_recording_enabled, :boolean, default: true
-
-    field :default_recording_visibility, Ecto.Enum,
-      values: ~w[private unlisted public]a,
-      default: :unlisted
-
+    field :default_recording_visibility, Ecto.Enum, values: ~w[private unlisted public]a
+    field :default_stream_visibility, Ecto.Enum, values: ~w[private unlisted public]a
     field :last_login_at, :utc_datetime_usec
     field :is_admin, :boolean
 

lib/asciinema/streaming.ex

@@ -91,6 +91,7 @@ defmodule Asciinema.Streaming do
     |> change(
       public_token: generate_public_token(),
       producer_token: generate_producer_token(),
+      visibility: user.default_stream_visibility,
       theme_prefer_original: user.theme_prefer_original
     )
     |> put_assoc(:user, user)

lib/asciinema_admin/controllers/user_controller.ex

@@ -10,11 +10,11 @@ defmodule AsciinemaAdmin.UserController do
   end
 
   def new(conn, _params) do
-    render(conn, :new, changeset: Accounts.new_user())
+    render(conn, :new, changeset: Accounts.build_user())
   end
 
   def create(conn, %{"user" => attrs}) do
-    case Accounts.create_user(attrs) do
+    case Asciinema.create_user(attrs) do
       {:ok, user} ->
         redirect(conn, to: ~p"/admin/users/#{user}")
 

lib/asciinema_web/controllers/user_controller.ex

@@ -116,6 +116,7 @@ defmodule AsciinemaWeb.UserController do
 
     render(conn, "edit.html",
       changeset: changeset,
+      streaming_mode: Streaming.mode(),
       stream_recording_mode: Streaming.recording_mode(),
       clis: clis
     )

lib/asciinema_web/controllers/user_html/edit.html.heex

@@ -80,7 +80,8 @@
         <legend>Defaults</legend>
 
         <p>
-          The settings below control the defaults for your uploaded recordings. <br />
+          The settings below control the defaults for <strong>new</strong>
+          recordings and streams. <br />
           <br />
         </p>
 
@@ -138,7 +139,66 @@
               </small>
             </div>
             <small class="form-text text-muted">
-              NOTE: This setting applies to *new* uploads. Existing recordings are not affected by changes to this setting.
+              NOTE: Existing recordings are not affected by changes to this setting.
+            </small>
+          </div>
+        </div>
+
+        <div :if={@streaming_mode == :dynamic} class="form-group row">
+          <.label for={f[:default_stream_visibility]} class="col-3 col-form-label">
+            Stream visibility
+          </.label>
+          <div class="col-9 visibility-radios">
+            <div class="form-check">
+              <input
+                type="radio"
+                name="user[default_stream_visibility]"
+                id="user_default_stream_visibility_public"
+                value="public"
+                checked={f[:default_stream_visibility].value == :public}
+                class="form-check-input"
+              />
+              <label for="user_default_stream_visibility_public" class="form-check-label">
+                Public
+              </label>
+              <small class="form-text text-muted">
+                Anyone can view, listed on your public profile
+              </small>
+            </div>
+            <div class="form-check">
+              <input
+                type="radio"
+                name="user[default_stream_visibility]"
+                id="user_default_stream_visibility_unlisted"
+                value="unlisted"
+                checked={f[:default_stream_visibility].value == :unlisted}
+                class="form-check-input"
+              />
+              <label for="user_default_stream_visibility_unlisted" class="form-check-label">
+                Unlisted
+              </label>
+              <small class="form-text text-muted">
+                Only people with the link can view
+              </small>
+            </div>
+            <div class="form-check">
+              <input
+                type="radio"
+                name="user[default_stream_visibility]"
+                id="user_default_stream_visibility_private"
+                value="private"
+                checked={f[:default_stream_visibility].value == :private}
+                class="form-check-input"
+              />
+              <label for="user_default_stream_visibility_private" class="form-check-label">
+                Private
+              </label>
+              <small class="form-text text-muted">
+                Only accessible by you
+              </small>
+            </div>
+            <small class="form-text text-muted">
+              NOTE: Existing streams are not affected by changes to this setting.
             </small>
           </div>
         </div>

priv/repo/migrations/20250307115515_add_default_stream_visibility_to_users.exs

@@ -0,0 +1,9 @@
+defmodule Asciinema.Repo.Migrations.AddDefaultStreamVisibilityToUsers do
+  use Ecto.Migration
+
+  def change do
+    alter table(:users) do
+      add :default_stream_visibility, :stream_visibility, null: false, default: "unlisted"
+    end
+  end
+end

test/asciinema_test.exs

@@ -8,21 +8,29 @@ defmodule AsciinemaTest do
   @urls Asciinema.TestUrlProvider
 
   describe "create_user/1" do
-    test "succeeds when email not taken" do
-      assert {:ok, _} = Asciinema.create_user_from_email("[email protected]")
-      assert {:error, :email_taken} = Asciinema.create_user_from_email("[email protected]")
-      assert {:error, :email_taken} = Asciinema.create_user_from_email("[email protected]")
+    test "succeeds for valid attrs" do
+      assert {:ok, _} = Asciinema.create_user(%{email: "[email protected]", username: "test"})
+    end
+
+    test "fails for invalid attrs" do
+      assert {:error, %Ecto.Changeset{}} =
+               Asciinema.create_user(%{email: "[email protected]", username: "a"})
     end
   end
 
   describe "create_user_from_sign_up_token/1" do
     test "succeeds when email not taken" do
-      # TODO don't reach to Accounts
-      {:ok, {:sign_up, token, _email}} =
-        Asciinema.Accounts.generate_login_token("[email protected]")
+      {:ok, {:sign_up, token, _email}} = Asciinema.generate_login_token("[email protected]")
 
       assert {:ok, _} = Asciinema.create_user_from_sign_up_token(token)
     end
+
+    test "fails when email address taken" do
+      {:ok, {:sign_up, token, _email}} = Asciinema.generate_login_token("[email protected]")
+      insert(:user, email: "[email protected]")
+
+      assert Asciinema.create_user_from_sign_up_token(token) == {:error, :email_taken}
+    end
   end
 
   describe "send_login_email/3" do

test/support/factory.ex

@@ -9,7 +9,9 @@ defmodule Asciinema.Factory do
     %User{
       username: sequence(:username, &"username-#{&1}"),
       email: sequence(:email, &"email-#{&1}@example.com"),
-      auth_token: Crypto.random_token(20)
+      auth_token: Crypto.random_token(20),
+      default_recording_visibility: :unlisted,
+      default_stream_visibility: :unlisted
     }
   end